摸了好一陣子,才弄明白AS3.0的加載機制.
還是堅持自己的原則,從適用的角度做記錄!下面分別講述AS3各加載事件與類!
一: Loader類在AS3.0里把所有事件,屬性,加載等都集中在某個對象上了.且加載對象與各觸發事件也進行了分工,這和2.0時期,用onEnterFrame和不斷檢測加載百分比強多了!
Loader繼承了基類DisplayObjectContainer,所以他可以也必須當作一個對象用addChild添加才能工作.
Loader 類可用于加載 SWF 文件或圖像（JPG、PNG 或 靜態GIF）文件。 使用 load() 方法來啟動加載。 被加載的顯示對象將作為 Loader 對象的子級添加。
例:
var loadimg: Loader = new Loader();
var url:String = "http://www.shch8.com/v2007/up/UploadFile/200769182617-1.gif"
var urlReq:URLRequest = new URLRequest();
urlReq.url=url;
loadimg.load(urlReq);
addChild(loadimg);
和2.0和比,還有一點區別,這里加載時要先把字符串地址轉化為url加載對象,在程序中的第三行是直接設置加載對象的url屬性的,也可以這樣寫urlReq = new URLRequest(url),除了url屬性還有幾個公共屬性，一般很少用到如：method用來控制get還是post提交方式。
因為把加載當作一個對象了,所以就不需要象2.0時期一樣,新建一個影片來裝載加對的物體loadMovie(“myimg.jpg”,”mv”)，我們可以直接設置他的x/y軸或寬高。還有Loader對象是二進制方式加載swf了，在flash9之前我們做加載條是用影片的getBytesLoaded和getBytesTotal來檢測的是否加載完成。這不是真正意義上的加載，只是判斷幀的加載數，所以會出現類似情況，加載到20%停了很久突然跳到90%因為那一幀放了整個影片70%的數據。以前在藍色里有討論過這個話題，還有人說是MM在走江湖！呵，現在解決了！
Loader的所有方法：
1. Loader()
創建一個可用于加載文件（如 SWF、JPEG、GIF 或 PNG 文件）的 Loader 對象。
2. close(): void
取消當前正在對 Loader 實例執行的 load() 方法操作。
3.load(request: URLRequest, context: LoaderContext = null):void
將 SWF、JPEG、漸進式 JPEG、非動畫 GIF 或 PNG 文件加載到此 Loader 對象的子對象中。
4.loadBytes(bytes:ByteArray, context: LoaderContext = null):void
從 ByteArray 對象中所存儲的二進制數據中加載。
5.unload():void
刪除此 Loader 對象中使用 load() 方法加載的子項。
二: LoaderInfo事件機制LoaderInfo非常好用，他是繼承EventDispatcher對象用來檢測網絡加載狀態。可以把加載動作細細地解剖出來。
原來在flash9之前，我們絞盡腦汁去獲取加載來的swf的寬度、高度、幀頻、版本等數據，但一直沒研究出好的方法現在LoaderInfo可以做到能獲取加載對象的各屬性，這點很好有時用swf來加載不確定swf時很有用，可以用那些屬性來重新設置主swf。
加載對象所加載數據的實時檢測上，PROGRESS事件可以取代以前用onEnterFrame的瘋狂檢測工作。當然2.0的也有自己的事件，只是很少人用！
LoaderInfo所繼承的所有事件：
1.complete(事件參數Event. COMPLETE)
成功加載數據后調度。
2.HttpStatus(事件參數HTTPStatusEvent.HTTP_STATUS)
在通過 HTTP 發出網絡請求并且 Flash Player 可以檢測到 HTTP 狀態代碼時調度。
3. Init(事件參數Event.INIT)
已加載的 SWF 文件的屬性和方法可訪問時調度。
4.IoError(事件參數IOErrorEvent.IO_ERROR)
在發生導致加載操作失敗的輸入或輸出錯誤時調度。
5.Open(事件參數Event.OPEN)
在加載操作開始時調度。
6.Progress(事件參數ProgressEvent.PROGRESS)
在下載操作過程中收到數據時調度。
7.Unload(事件參數Event.UNLOAD)
每次使用 Loader 對象的 unload() 方法刪除已加載對象時，或者當同一 Loader 對象執行第二次加載并且在加載開始之前刪除了原始內容時，由 對象調度。
具體測試例子請看loadjpg.swf與loadswf.swf
LoaderInfo的獲取swf屬性時要等swf加載完才能獲取，也就是在COMPLETE事件里獲取
如: loadswf.contentLoaderInfo.addEventListener(Event.COMPLETE, loadcom)
function loadcom(the:Event):void {
trace("AS版本:AS"+the.target.actionScriptVersion+".0")
trace("swf版本:flash"+the.target.swfVersion+".0")
trace("swf寬:"+the.target.width+"swf高:"+the.target.height)
trace("swf幀頻:"+the.target.frameRate+"幀/秒")
}
事件觸發的各個順序分別是
OPEN>>INIT>>HTTP>> COMPLETE
加載操作開始時調度>>進入事件 SWF 文件的屬性和方法調度>>狀態事件通過 HTTP 發出網絡請求并且 Flash Player檢測到 HTTP 狀態代碼>>加載完成
例(需要flashPlay9.0播放器才能正常測試):
三：跨域加載的安全機制你可以加載來自任何可訪問源的內容。
如果執行調用的 SWF 文件位于網絡沙箱中并且要加載的文件是本地的，則不允許加載。
如果加載的內容為用 ActionScript 3.0 編寫的 SWF 文件，那么除非可以通過調用加載的內容文件中的 System.allowDomain() 或 System.allowInsecureDomain() 方法來允許跨腳本排列，否則另一個安全沙箱中的 SWF 文件不能對它執行跨腳本操作。
如果被加載的內容為 AVM1 SWF 文件（用 ActionScript 1.0 或 2.0 編寫），則 AVM2 SWF 文件（用 ActionScript 3.0 編寫）不能對它執行跨腳本操作。 但是，可以通過使用 LocalConnection 類在兩個 SWF 文件之間實現通信。
如果被加載的內容為圖像，則除非該 SWF 文件的域包含在該圖像原始域的跨域策略文件中，否則安全沙箱之外的 SWF 文件無法訪問其數據。
在只能與本地文件系統的內容交互的沙箱中的影片剪輯不能對只能與遠程內容交互的沙箱中的影片剪輯使用腳本，反之亦然。
四：主場景加載條制作我們都知道，AS2.0是用_root. getBytesLoaded()和_root. getBytesTotal()來判斷swf是否被加載完，但在3.0里面_root，_global，_parent等原來的”骨干職工”都被開除了！取代他的是stage，對于場影設置，他是一手遮天了如設置swf全屏，對齊方式，顯視品質等。但stage只繼承了DisplayObjectContainer一部分屬性，可用的還太少了。
在做場影加載條時，我們要獲取場影的加載情況。要想辦法把上面講的LoadInfo事件添加到主場景去，用stage是做不到的。但可以用顯視類DisplayObject 添加，他繼承了 EventDispatcher，可以直接用他的屬性指定主場景來添加，DisplayObject和屬性和原來的movieClip還是很像的，只是前面不用加下劃線作區分了如：root.loaderInfo.addEventListener()
用root調度loaderInfo：
root.loaderInfo.addEventListener(ProgressEvent.PROGRESS, loadshow)
function loadshow(the: ProgressEvent):void {
var loadnum:Number=int(the.bytesLoaded/the.bytesTotal*100);
showtxt.text="load:"+loadnum + "%";
gotoAndStop(loadnum);
}
五：使用系統圖片與加載條等組件寫的加載類package myAs{
import fl.containers.UILoader;//圖片加載組件
import fl.controls.Label;//文本組件
import fl.controls.ProgressBar;//進度條
import flash.events.Event;//輸入事件類,如果代碼寫在幀上,可不用輸入
import flash.events.ProgressEvent;//輸入事, 件類
import flash.text.TextField;//引進文本類
import flash.net.URLRequest;
import fl.controls.ProgressBarMode;
import flash.display.Sprite;
import flash.text.TextFieldAutoSize;//調整類
public class loadimg extends Sprite {
private var url:String = "http://image.cnool.net/picn/2005/ompic030b.jpg"
private var loadbox: ProgressBar = new ProgressBar();
private var imgbox: UILoader = new UILoader();
private var showtxt: Label = new Label();
private var titleTxt:TextField=new TextField();
//注意:上面的幾個對象要聲明在這里,不能放在主函數里聲明,這樣loadeven()等事件函數里才能認到
public function loadimg() {
titleTxt.htmlText="圖片加載示例:";
addChild(titleTxt);
titleTxt.x=0;
titleTxt.y=10;
showtxt.autoSize = TextFieldAutoSize.LEFT;
showtxt.text = "";
showtxt.move(150, 10);
addChild(showtxt);
loadbox.mode = ProgressBarMode.MANUAL;
loadbox.move(150, 30);
addChild(loadbox);
imgbox.load(new URLRequest(url));
imgbox.addEventListener(ProgressEvent.PROGRESS, loadeven);
imgbox.addEventListener(Event.COMPLETE, loadend);
imgbox.setSize(550,400);
imgbox.move(0, 40);
addChild(imgbox);
}
private function loadeven(event: ProgressEvent):void {//事件:加載進度顯視
var uiLdr:UILoader = event.currentTarget as UILoader;
var kbLoaded:String = Number(uiLdr.bytesLoaded / 1024).toFixed(1);
var kbTotal:String = Number(uiLdr.bytesTotal / 1024).toFixed(1);
showtxt.text = kbLoaded + "/" + kbTotal + " KB" + " (load:" + Math.round(uiLdr.percentLoaded) + "%)";
loadbox.setProgress(event.bytesLoaded, event.bytesTotal);
}
private function loadend(event: Event):void {//事件:加載完成 刪除事件
//showtxt.visible = false;
//loadbox.visible = false;//加載完成后隱藏進度條
imgbox.removeEventListener(ProgressEvent.PROGRESS, loadeven);
imgbox.removeEventListener(Event.COMPLETE, loadend);
}
}
}
使用組件就輕松多了,不用考慮那么多。只是開發出一個適用的產品最好不要去用官方的組件。自己去寫過，寫過適合自己的組件。不過CS3的Uiloader感覺很不錯！