?我所使用的編譯器和平臺：WindowsXP + 賽揚1G + VC6(主要工具)\Delphi6\C++Builder6;

一：函數調用約定;
??? 函數調用約定是函數調用者和被調用的函數體之間關于參數傳遞、返回值傳遞、堆棧清除、寄存器使用的一種約定;
??? 它是需要二進制級別兼容的強約定,函數調用者和函數體如果使用不同的調用約定,將可能造成程序執行錯誤,必須把它看作是函數聲明的一部分;

二：常見的函數調用約定;

VC6中的函數調用約定;

??????? 調用約定??????? 堆棧清除??? 參數傳遞
??????? __cdecl???????? 調用者????? 從右到左,通過堆棧傳遞
??????? __stdcall?????? 函數體????? 從右到左,通過堆棧傳遞
??????? __fastcall????? 函數體????? 從右到左,優先使用寄存器(ECX,EDX),然后使用堆棧
??????? thiscall??????? 函數體????? this指針默認通過ECX傳遞,其它參數從右到左入棧

__cdecl是C\C++的默認調用約定; VC的調用約定中并沒有thiscall這個關鍵字,它是類成員函數默認調用約定;
C\C++中的main(或wmain)函數的調用約定必須是__cdecl,不允許更改;
默認調用約定一般能夠通過編譯器設置進行更改,如果你的代碼依賴于調用約定,請明確指出需要使用的調用約定;

Delphi6中的函數調用約定;

??????? 調用約定??????? 堆棧清除??? 參數傳遞
??????? register??????? 函數體????? 從左到右,優先使用寄存器(EAX,EDX,ECX),然后使用堆棧
??????? pascal????????? 函數體????? 從左到右,通過堆棧傳遞
??????? cdecl?????????? 調用者????? 從右到左,通過堆棧傳遞(與C\C++默認調用約定兼容)
??????? stdcall???????? 函數體????? 從右到左,通過堆棧傳遞(與VC中的__stdcall兼容)
??????? safecall??????? 函數體????? 從右到左,通過堆棧傳遞(同stdcall)

Delphi中的默認調用約定是register,它也是我認為最有效率的一種調用方式,而cdecl是我認為綜合效率最差的一種調用方式;
VC中的__fastcall調用約定一般比register效率稍差一些;

C++Builder6中的函數調用約定;

??????? 調用約定??????? 堆棧清除??? 參數傳遞
??????? __fastcall????? 函數體????? 從左到右,優先使用寄存器(EAX,EDX,ECX),然后使用堆棧 (兼容Delphi的register)
??????? (register與__fastcall等同)
??????? __pascal??????? 函數體????? 從左到右,通過堆棧傳遞
??????? __cdecl???????? 調用者????? 從右到左,通過堆棧傳遞(與C\C++默認調用約定兼容)
??????? __stdcall?????? 函數體????? 從右到左,通過堆棧傳遞(與VC中的__stdcall兼容)
??????? __msfastcall??? 函數體????? 從右到左,優先使用寄存器(ECX,EDX),然后使用堆棧(兼容VC的__fastcall)

?

常見的函數調用約定中,只有cdecl約定需要調用者來清除堆棧;
C\C++中的函數支持參數數目不定的參數列表,比如printf函數;由于函數體不知道調用者在堆棧中壓入了多少參數,
所以函數體不能方便的知道應該怎樣清除堆棧,那么最好的辦法就是把清除堆棧的責任交給調用者;
這應該就是cdecl調用約定存在的原因吧;

VB一般使用的是stdcall調用約定;(ps：有更強的保證嗎)
Windows的API中,一般使用的是stdcall約定;(ps: 有更強的保證嗎)
建議在不同語言間的調用中(如DLL)最好采用stdcall調用約定,因為它在語言間兼容性支持最好;

三:函數返回值傳遞方式
?? 其實，返回值的傳遞從處理上也可以想象為函數調用的一個out形參數； 函數返回值傳遞方式也是函數調用約定的一部分；
?? 有返回值的函數返回時：一般int、指針等32bit數據值(包括32bit結構)通過eax傳遞，(bool,char通過al傳遞，short通過ax傳遞),特別的__int64等64bit結構(struct) 通過edx,eax兩個寄存器來傳遞(同理：32bit整形在16bit環境中通過dx,ax傳遞); 其他大小的結構(struct)返回時把其地址通過eax返回；(所以返回值類型不是1,2,4,8byte時，效率可能比較差)
?? 參數和返回值傳遞中，引用方式的類型可以看作與傳遞指針方式相同；
?? float\double(包括Delphi中的extended)都是通過浮點寄存器st(0)返回；

四：通過VC中的C++例子和產生出的匯編清單來對函數調用約定進行說明;

(ps:后面雖然列出了很多匯編,但是我做了很詳細的注釋,我希望那些對匯編感到“恐懼”的人
也能順利的閱讀; 并為那些想在VC中使用匯編的人提供一些幫助

A:
測試代碼：

int x;
int __cdecl add(int a,int b) { return a+b; }//使用__cdecl調用約定
int main(int argc, char* argv[])
{
??? x=add(1,2);
??? return 0;
}

?

; Debug模式編譯后得到的匯編代碼

PUBLIC????? ?x@@3HA??????????????????? ; x
_BSS??????? SEGMENT
?x@@3HA???? DD??????? 01H DUP (?)????? ; x變量
_BSS??????? ENDS
PUBLIC????? ?add@@YAHHH@Z????????????? ; add
PUBLIC????? _main
EXTRN?????? __chkesp:NEAR
;?????????? COMDAT?????? _main
_TEXT?????? SEGMENT

_main?????? PROC NEAR????????????????? ; COMDAT??????? //main函數體

? push??? ebp???????? ; //保存ebp的值到堆棧,退出函數前用pop ebp恢復
? mov???? ebp, esp??? ; //ebp指向當前堆棧; 函數中可以通過ebp來進行堆棧訪問
? sub???? esp, 64???? ; //在堆棧中開辟64byte局部空間

????????????????????? ; //說明：這三條匯編指令是很多函數體開始的慣用法;
????????????????????? ; //用ebp指向堆棧(不會改變);并通過ebp來訪問參數和局部變量;

? push??? ebx???????? ; //一般按照函數間調用的約定,函數中可以自由使用eax,ecx,edx;
? push??? esi???????? ; //其它寄存器如果需要使用則需要保存,用完時恢復；也就是寄存器的使用約定； 這也使函數調用約定的一部分；
? push??? edi???????? ; //即:在函數中調用了別的函數后,eax,ecx,edx很可能已經改變,
????????????????????? ; //而其它寄存器(ebx,esi,edi,ebp)的值可以放心繼續使用(esp除外)

? lea??? edi, DWORD PTR [ebp-64]
? mov??? ecx, 16???????????????? ; 00000010H
? mov??? eax, -858993460???????? ; ccccccccH
? rep stosd????????????????????? ; //前面開辟的(16*4)byte局部空間全部填充0xCC
???????????????????????????????? ; //注意: 0xCC是調試中斷(__asm int 3)的指令碼,所以可以想象,當
???????????????????????????????? ; //程序錯誤的跳轉到這個區域進行執行時將產生調試中斷

? push?? 2?????????????????????? ; //代碼: x=add(1,2);?
? push?? 1?????????????????????? ; //從右到左入棧? (__cdecl調用約定!!!)
? call?? ?add@@YAHHH@Z?????????? ; 調用add函數;call指令將把下一條指令的地址(返回地址)壓入堆棧
? add??? esp, 8????????????????? ; add函數調用完以后,調用者負責清理堆棧 (__cdecl調用約定!!!)
???????????????????????????????? ; 兩個int型參數共使用了8byte空間的堆棧
? mov??? DWORD PTR ?x@@3HA, eax? ; 將add函數的返回值存入x變量中,可以看出add函數的返回值放在eax中

? xor??? eax, eax????? ; //原代碼:return 0;?? 執行eax清零,main函數的返回值0放在eax中

? pop??? edi
? pop??? esi
? pop??? ebx?????????? ; //恢復edi,esi,ebx寄存器
? add??? esp, 64?????? ; //恢復64byte局部空間
? cmp??? ebp, esp???????????????
? call??? __chkesp???? ; //到這里時應該ebp==esp, Debug版進行確認,如果不等,拋出異常等
? mov??? esp, ebp
? pop??? ebp?????????? ; //恢復ebp寄存器
? ret??? 0
_main???? ENDP
_TEXT???? ENDS

;//下面是add函數的代碼,就不用解釋的像上面那么詳細了

;??????? COMDAT? ?add@@YAHHH@Z
_TEXT??????????? SEGMENT
_a$ = 8??????????????????????????????? ;//參數a相對于堆棧偏移8
_b$ = 12?????????????????????????????? ;//參數b相對于堆棧偏移12

?add@@YAHHH@Z PROC NEAR??????????????? ; add, COMDAT??????? //add函數體

? push??????? ebp
? mov???????? ebp, esp
? sub???????? esp, 64????????????????? ; 00000040H
? push??????? ebx
? push??????? esi
? push??????? edi
? lea???????? edi, DWORD PTR [ebp-64]
? mov???????? ecx, 16????????????????? ; 00000010H
? mov???????? eax, -858993460????????? ; ccccccccH
? rep stosd

? mov???????? eax, DWORD PTR _a$[ebp]? ;將參數a的值移動到eax
? add???????? eax, DWORD PTR _b$[ebp]? ;將參數b的值累加到eax; 可以看出返回值通過eax返回

? pop???????? edi
? pop???????? esi
? pop???????? ebx
? mov???????? esp, ebp
? pop???????? ebp
? ret???????? 0???????????????????? ; 函數體不管堆棧的參數清理 (__cdecl調用約定!!!)
??????????????????????????????????? ; ret指令將取出call指令壓入的返回地址,并跳轉過去繼續執行

?add@@YAHHH@Z ENDP????????????????? ; add
_TEXT??????? ENDS
END

; 再來看一下Release模式編譯后得到的匯編代碼
; 可以看出,這比Debug模式少了很多的匯編指令,速度當然可能更快了;不再做詳細說明了,請對照上面的解釋

PUBLIC??????? ?x@@3HA?????????????????? ; x
_BSS????????? SEGMENT
?x@@3HA?????? DD??????? 01H DUP (?)???? ; x
_BSS????????? ENDS
PUBLIC??????? ?add@@YAHHH@Z???????????? ; add
PUBLIC??????? _main
;???????????? COMDAT??????????? _main
_TEXT???????? SEGMENT

_main???????? PROC NEAR???????????????? ; COMDAT??????? //main函數體

? push??? 2
? push??? 1?????????????????????? ; //從右到左入棧? (__cdecl調用約定!!!)
? call??? ?add@@YAHHH@Z?????????? ; //調用add函數;
? mov???? DWORD PTR ?x@@3HA, eax? ; x
? add???? esp, 8????????????????? ; //調用者負責清理堆棧 (__cdecl調用約定!!!)

? xor???? eax, eax
? ret???? 0
_main??????? ENDP
_TEXT??????? ENDS

;??????????? COMDAT?? ?add@@YAHHH@Z
_TEXT??????? SEGMENT
_a$ = 8
_b$ = 12

?add@@YAHHH@Z PROC NEAR??????????? ; add, COMDAT??????? //add函數體

? mov?? eax, DWORD PTR _b$[esp-4]? ;將參數b的值移動到eax
? mov?? ecx, DWORD PTR _a$[esp-4]? ;將參數a的值移動到ecx
? add?? eax, ecx?????????????????? ;將ecx的值累加到eax; 返回值通過eax傳遞
? ret?? 0????????????????????????? ;函數體不管堆棧的參數清理 (__cdecl調用約定!!!)
?add@@YAHHH@Z ENDP???????????????? ; add
_TEXT???????? ENDS
END

?

下面的分析中將只給出Release模式編譯后的匯編代碼

B:
聲明add函數為__stdcall調用約定

int x;
int __stdcall add(int a,int b) { return a+b; }
int main(int argc, char* argv[])
{
??? x=add(1,2);
??? return 0;
}

;來看產生的匯編代碼：

?

; //main函數體
? push??? 2
? push??? 1??????????????????????? ; //從右到左入棧
? call??? ?add@@YGHHH@Z??????????? ; add
? mov???? DWORD PTR ?x@@3HA, eax?? ; x
? xor???? eax, eax
? ret???? 0

; //add函數體
? mov???? eax, DWORD PTR _b$[esp-4]
? mov???? ecx, DWORD PTR _a$[esp-4]
? add???? eax, ecx
? ret???? 8??????????????????????? ; //函數體負責清棧 ;兩個int型參數共使用了8byte空間的堆棧

C:
聲明add函數為__fastcall調用約定

int x;
int __fastcall add(int a,int b) { return a+b; }
int main(int argc, char* argv[])
{
??? x=add(1,2);
??? return 0;
}

;來看產生的匯編代碼：

; //main函數體
? mov??? edx, 2??????????????????? ; b通過寄存器edx傳遞
? mov??? ecx, 1??????????????????? ; a通過寄存器ecx傳遞
? call?? ?add@@YIHHH@Z???????????? ; add
? mov??? DWORD PTR ?x@@3HA, eax??? ; x
? xor??? eax, eax
? ret??? 0

; //add函數體
? lea??? eax, DWORD PTR [ecx+edx]? ; //a,b參數值已經在ecx,edx中,該句將這兩個值的和放到eax作為返回值;
? ret??? 0???????????????????????? ; //這里應該函數體負責清棧 ;但因為兩個參數已經通過寄存器傳遞
?????????????????????????????????? ; //了,沒有使用堆棧,所以ret 0;

D:
來看一下類的成員函數的調用：

struct T
{
??????? int start0;
??????? T():start0(1){ }
??????? int? add(int a,int b); //類成員函數;只要不明確聲明調用約定則默認使用thiscall調用約定;
};
int? T::add(int a,int b) { return (*this) dot start0+a+b; }

int x;
int main(int argc, char* argv[])
{
??????? T t;
??????? x=t.add(1,2);
??????? return 0;
}

來看產生的匯編代碼：

; //main函數體
? push??? ecx???????????????????????? ; //保存ecx
? push??? 2
? push??? 1?????????????????????????? ; //參數從右到左入棧
? lea???? ecx, DWORD PTR _t$[esp+12]? ; //t的地址保存到ecx
? mov???? DWORD PTR _t$[esp+12], 1??? ; //執行t::start0=1;
? call??? ?add@T@@QAEHHH@Z??????????? ; //調用T::add函數,這時ecx中存放了t的的地址(this指針);
? mov???? DWORD PTR ?x@@3HA, eax????? ; x
? xor???? eax, eax
? pop???? ecx
? ret???? 0

; //T::add函數體
? mov???? eax, DWORD PTR [ecx]??????? ; //通過this指針(保存在ecx)將start0的值移動到eax
? mov???? ecx, DWORD PTR _a$[esp-4]?? ; //把a的值移動到ecx; this的值將丟失,但函數體中已經不需要了
? add???? eax, ecx??????????????????? ; //將a的值累加到eax
? mov???? ecx, DWORD PTR _b$[esp-4]?? ; //把b的值移動到ecx;
? add???? eax, ecx??????????????????? ; //將b的值累加到eax
? ret???? 8?????????????????????????? ; //函數體負責清棧 ;

五: 其他

1 dot 在VC中實現一個函數體時可以使用__declspec(naked)聲明,它告訴編譯器,不要為函數體自動產生開始和結束碼;
2.在VC6中,想得到匯編代碼清單,設置方法為：

引用:[Project]->[Setting...]->[C++]->[Category:]->[Listing Files]->[Listing file type:]->[Assembily ,...]

3.VC6中嵌入匯編代碼的方式為：

??????????? __asm { <匯編語句s> }
???????? 或 __asm <一條匯編語句>

4.VC6中重新設定函數使用的默認調用約定的方法是：
引用:
在[Project]->[Setting...]->[C++]->[Project Options:]中增加編譯設置
比如：/Gd 代表__cdecl; /Gr 代表__fastcall; /Gz 代表__stdcall

?

參考資料：
MSDN:Calling Conventions;
Delphi6\C++Builder6幫助;
請用www.google.com和www.baidu.com搜索“調用約定”或“Calling Conventions”;

本文引用通告地址： http://blog.csdn.net/avalonBBS/services/trackbacks/229300.aspx