端口
前面講過(guò)，各種存儲(chǔ)器都和CPU的地址線、數(shù)據(jù)線、控制線相連。CPU在操控它們的時(shí)候，把它們都當(dāng)作內(nèi)存來(lái)對(duì)待，把它們總的看做一個(gè)由若干存儲(chǔ)單元組成的邏輯存儲(chǔ)器，這個(gè)邏輯器我們稱其為內(nèi)存地址空間。
在PC機(jī)系統(tǒng)中，和CPU通過(guò)總線相連的芯片除各種存儲(chǔ)器外，還有以下3種芯片：
1）各種接口卡（比如：網(wǎng)卡、顯卡）上的接口芯片，它們控制接口卡進(jìn)行工作；
2）主板上的接口芯片，CPU通過(guò)它們對(duì)部分外設(shè)進(jìn)行訪問(wèn)；
3）其他芯片，用來(lái)存儲(chǔ)相關(guān)的系統(tǒng)信息，或進(jìn)行相關(guān)的輸入輸出處理。
在這些芯片中，都有一組可以由CPU讀寫(xiě)的寄存器。這些寄存器，它們?cè)谖锢砩峡赡芴幱诓煌男酒校撬鼈冊(cè)谝韵聝牲c(diǎn)上相同：
1）都和CPU的總線相連，當(dāng)然這種連接是通過(guò)它們所在的芯片進(jìn)行的；
2）CPU對(duì)它們進(jìn)行讀或?qū)懙臅r(shí)候都通過(guò)控制線向它們所在的芯片發(fā)出端口讀寫(xiě)命令。
可見(jiàn)，從CPU的角度，將這些寄存器都當(dāng)作端口，對(duì)它們進(jìn)行統(tǒng)一編址，從而建立了一個(gè)統(tǒng)一的端口地址空間。每一個(gè)端口在地址空間中都有一個(gè)地址。
CPU可以直接讀寫(xiě)3個(gè)地方的數(shù)據(jù)：
1）CPU內(nèi)部的寄存器；
2）內(nèi)存單元；
3）端口中。（芯片中的寄存器）
端口的讀寫(xiě)
在訪問(wèn)端口的時(shí)候，CPU通過(guò)端口地址來(lái)定位端口。因?yàn)槎丝谒诘男酒?/span>CPU通過(guò)總路線相連，所以，端口地址和內(nèi)存地址一樣，通過(guò)地址總路線來(lái)傳送。在PC系統(tǒng)中，CPU最多可以定位64K個(gè)不同的端口。則端口地址的范圍為0~65535。
對(duì)端口的讀寫(xiě)不能用mov，push，pop等內(nèi)存讀寫(xiě)指令。
端口的讀寫(xiě)指令只有兩條：in和out，分別用于從端口讀出數(shù)據(jù)和往端口寫(xiě)入數(shù)據(jù)。
我們來(lái)看一下CPU執(zhí)行內(nèi)存訪問(wèn)指令和端口訪問(wèn)指令時(shí)候，總線上的信息：
1）訪問(wèn)內(nèi)存：
mov ax,ds:[8] ;假設(shè)執(zhí)行前(ds)=0
執(zhí)行時(shí)與總路線相關(guān)的操作：
（1）CPU通過(guò)地址線將地址信息8發(fā)出；
（2）CPU通過(guò)控制線發(fā)出內(nèi)存讀命令，選中存儲(chǔ)器芯片，并通知它，將要從中讀取數(shù)據(jù)；
（3）存儲(chǔ)器將8號(hào)單元中的數(shù)據(jù)通過(guò)數(shù)據(jù)線送入CPU。
2）訪問(wèn)端口：
in al,60h ;從60h號(hào)端口讀入一個(gè)字節(jié)
執(zhí)行時(shí)與總路線相關(guān)的操作：
（1）CPU通過(guò)地址線將地址信息60h發(fā)出；
（2）CPU通過(guò)控制線發(fā)出端口讀命令，選中端口所在的芯片，并通知它，將要從中讀取數(shù)據(jù)；
（3）端口所在的芯片將60h端口中的數(shù)據(jù)通過(guò)數(shù)據(jù)線送入CPU。
在in和out指令中，只能使用ax或al來(lái)存放從端口中讀入的數(shù)據(jù)或要發(fā)送到端口中的數(shù)據(jù)。訪問(wèn)8位端口時(shí)用al，訪問(wèn)16位端口時(shí)用ax。
對(duì)0~255以內(nèi)的端口進(jìn)行讀寫(xiě)時(shí)：
in al,20h ;從20h端口讀入一個(gè)字節(jié)
out 20h,al ;往20h端口寫(xiě)入一個(gè)字節(jié)
對(duì)256~65535的端口進(jìn)行讀寫(xiě)時(shí)，端口號(hào)放在dx中：
mov dx,3f8h ;將端口號(hào)3f8h送入dx
in al,dx ;從3f8h端口讀入一個(gè)字節(jié)
out dx,al ;向3f8h端口寫(xiě)入一個(gè)字節(jié)
CMOS RAM芯片
我們通過(guò)對(duì)CMOS RAM的讀寫(xiě)來(lái)體會(huì)一下對(duì)端口的訪問(wèn)。
PC機(jī)中，有一個(gè)CMOS RAM芯片，一般簡(jiǎn)稱為CMOS。此芯片的特征如下：
1）包含一個(gè)實(shí)時(shí)鐘和一個(gè)有128個(gè)存儲(chǔ)單元的RAM存儲(chǔ)器（早期的計(jì)算機(jī)為64個(gè)字節(jié)）。
2）該芯片靠電池供電。所以，關(guān)機(jī)后其內(nèi)部的實(shí)時(shí)鐘仍可正常工作，RAM中的信息不丟失。
3）128個(gè)字節(jié)的RAM中，內(nèi)部實(shí)時(shí)鐘占用0~0dh單元來(lái)保存時(shí)間信息，其余大部分單元用來(lái)保存系統(tǒng)配置信息，供系統(tǒng)啟動(dòng)時(shí)BIOS程序讀取。BIOS也提供了相關(guān)的程序，使我們可以在開(kāi)機(jī)的時(shí)候配置CMOS RAM中的系統(tǒng)信息。
4）該芯片內(nèi)部有兩個(gè)端口，端口地址為70h和71h。CPU通過(guò)這兩個(gè)端口來(lái)讀寫(xiě)CMOS RAM。
5）70h為地址端口，存放要訪問(wèn)的CMOS RAM單元的地址：71h為數(shù)據(jù)端口，存放從選定的CMOS RAM單元中讀取的數(shù)據(jù)。可見(jiàn)，CPU對(duì)CMOS RAM的讀寫(xiě)分兩步進(jìn)行了，比如：讀CMOS RAM的2號(hào)單元：
（1）將2送入端口70h；
（2）從71h讀出2號(hào)單元的內(nèi)容。
檢測(cè)點(diǎn)14.1
1）編程：讀取CMOS RAM的2號(hào)單元的內(nèi)容。
mov al,2h
out 70h,al ;把2寫(xiě)入地址端口。
in 71h,al ;把數(shù)據(jù)端口的內(nèi)容讀出放入al寄存器。
2）編程：向CMOS RAM的2號(hào)單元寫(xiě)入0。
mov al,2h
out 70h,al ;把2寫(xiě)入地址端口
mov al,0
out 71h,al ;把0寫(xiě)入數(shù)據(jù)端口
shl和shr指令
shl和shr是邏輯移位指令。
shl是邏輯左移指令，它的功能為：
1）將一個(gè)寄存器或內(nèi)存單元中的數(shù)據(jù)向左移位；
2）將最后移出的一位寫(xiě)入CF中；
3）最低位用0補(bǔ)充。
指令：
mov al,01001000b
shl al,1 ;將al中的數(shù)據(jù)左移一位
執(zhí)行后(al)=10010000b，CF=0。
如果移動(dòng)位數(shù)大于1時(shí)，必須將移動(dòng)位數(shù)放在cl中。
比如，指令：
mov al,01010001b
mov cl,3
shl al,cl
執(zhí)行后(al)=10001000b，因?yàn)樽詈笠瞥龅囊晃皇?/span>1，所以CF=1。
可以看出，將X邏輯左移一位，相當(dāng)于執(zhí)行X=X*2。
shr是邏輯右移指令，它和shl所進(jìn)行的操作剛好相反：
1）將一個(gè)寄存器或內(nèi)存單元中的數(shù)據(jù)向右移位；
2）將最后移出的一位寫(xiě)入CF中。
3）最高位用0補(bǔ)充。
指令：
mov al,10000001b
shr al,1 ;將al中的數(shù)據(jù)右移一位
執(zhí)行后(al)=01000000b，CF=1
如果移動(dòng)位數(shù)大于1時(shí)，必須將移動(dòng)位數(shù)放在cl中。
比如，指令：
mov al,01010001b
mov cl,3
shr al,cl
執(zhí)行后(al)=00001010b，因?yàn)樽詈笠瞥龅囊晃皇?/span>0，所以CF=0。
可以看出將X邏輯右移一位，相當(dāng)于執(zhí)行X=X/2。
檢測(cè)點(diǎn)14.2
編程：用加法和移位指令計(jì)算(ax)=(ax)*10
提示：(ax)*10 = (ax)*2 + (ax)*8
assume cs:code
code segment
start: mov ax,1000h
mov bx,ax
shl bx,1 ;(ax)=(ax)*2
mov cl,3
shl ax,cl ;(ax)=(ax)*8
add ax,bx ;(ax)=(ax)*10
code ends
end start
CMOS RAM中存儲(chǔ)的時(shí)間信息
在CMOS RAM中，存放著當(dāng)前的時(shí)間：年、月、日、時(shí)、分、秒。這6個(gè)信息的長(zhǎng)度都為1個(gè)字節(jié)，存放單元為：
秒：0 分：2 時(shí)：4 日：7 月：8 年：9
這些數(shù)據(jù)以BCD碼的方式存放。
BCD碼是以4位二進(jìn)制數(shù)表示十進(jìn)制數(shù)碼的編碼方法，如下表示：
|
十進(jìn)制
|
0
|
1
|
2
|
3
|
4
|
5
|
6
|
7
|
8
|
9
|
|
BCD碼
|
0000
|
0001
|
0010
|
0011
|
0100
|
0101
|
0110
|
0111
|
1000
|
1001
|
比如：數(shù)值26，用BCD碼表示為：0010 0110 （2 6）
可見(jiàn)，一個(gè)字節(jié)可表示兩個(gè)BCD碼。則CMOS RAM存儲(chǔ)時(shí)間信息的單元中，存儲(chǔ)了用兩個(gè)BCD碼表示的兩位十進(jìn)制數(shù)，高4位的BCD碼表示十位，低4位的BCD碼表示個(gè)位。比如：00010100b表示14。
編程：在屏幕中間顯示當(dāng)前的月份。
分析：這個(gè)程序主要做兩部分工作：
（1）從CMOS RAM的8號(hào)單元讀出當(dāng)前月份的BCD碼：
mov al,8 ;首先要向地址端口70h
out 70h,al ;寫(xiě)入要訪問(wèn)的單元的地址。
in al,71h ;然后，從數(shù)據(jù)端口71h中取得指定單元中的數(shù)據(jù)。
（2）將用BCD碼表示的月份以十進(jìn)制的形式顯示到屏幕上。
BCD碼值=十進(jìn)制數(shù)碼值，則BCD碼值+30h=十進(jìn)制數(shù)對(duì)應(yīng)的ASCII碼。
從CMOS RAM的8號(hào)單元讀出的一個(gè)字節(jié)中，包含了兩個(gè)BCD碼表示的兩位十進(jìn)制數(shù)，高4位的BCD碼表示十位，低4位的BCD碼表示個(gè)位。比如：00010100表示14。
我們需要進(jìn)行兩步工作：
1）將從CMOS RAM的8號(hào)單元中讀出的一個(gè)字節(jié)，分為兩個(gè)表示BCD碼值的數(shù)據(jù)。
mov ah,al ;al中為從CMOS RAM的8號(hào)單元讀出的數(shù)據(jù)
mov cl,4
shr ah,cl ;ah中為月份的十位數(shù)碼值
and al,00001111b ;al中為月份的個(gè)位數(shù)碼值
2）顯示(ah)+30h和(al)+30h對(duì)應(yīng)的ASCII碼字符。
完整程序如下：
assume cs:code
code segment
start:
mov al,8
out 70h,al
in al,71h ;從CMOS RAM的8號(hào)單元讀出當(dāng)前月份的BCD碼。
mov ah,al ;ah,al都存儲(chǔ)著當(dāng)前月份的BCD碼。
mov cl,4
shr ah,cl ;ah中內(nèi)容邏輯右移4位，則只剩下月份的十位數(shù)碼。
and al,00001111b ;al中內(nèi)容將只剩下月份的個(gè)位數(shù)碼。
add ah,30h
add al,30h ;得到十進(jìn)制數(shù)碼的ASCII碼值。
mov bx,0b800h
mov es,bx
mov byte ptr es:[160*12+40*2],ah ;顯示月份的十位數(shù)碼
mov byte ptr es:[160*12+40*2+2],al ;顯示月份的個(gè)位數(shù)碼
mov ax,4c00h
int 21h
code ends
end start