本章還有一個(gè)實(shí)驗(yàn)10 編寫子程序。但是本課程設(shè)計(jì)包括了寫的子程序的所有內(nèi)容，在代碼中也包含所有寫的子程序的代碼，所以直接看本課程設(shè)計(jì)的代碼就可以了。
在前面的學(xué)習(xí)中，有一個(gè)實(shí)驗(yàn)是將poweridea公司的數(shù)據(jù)按格式寫到一個(gè)table段中，而本課程設(shè)計(jì)是要求就數(shù)據(jù)寫到顯存以顯示在屏幕上，所以我們可以在以前的程序基礎(chǔ)上修改，比如可以保留以前的程序，先寫到table表，然后從table表讀到顯存。不過(guò)我這里的實(shí)現(xiàn)是去掉這些不必要的消耗，也刪掉了table表，使程序更高效。另外，在code段里面還有幾個(gè)子程序，代碼的關(guān)鍵部分也都做了注釋，實(shí)現(xiàn)如下：
PowerideaShow
DATAS SEGMENT
;此處輸入數(shù)據(jù)段代碼
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
;起始行：4
db 4
;各字段的列：year=8；收入=16；雇員=30；平均收入=42
db 8,16,30,42
;字符緩沖區(qū)
db 20 dup (0)
DATAS ENDS
STACKS SEGMENT
;此處輸入堆棧段代碼
dw 20 dup (0)
STACKS ENDS
CODES SEGMENT
ASSUME CS:CODES,DS:DATAS,SS:STACKS
START:
MOV AX,DATAS
MOV DS,AX
mov ax,STACKS
mov ss,ax
mov sp,40
mov bp,215
mov si,0 ;for year and summ
mov di,0 ;for ne
mov cx,21
show:
push cx
mov cl,0f2h ;顏色
;year 偏移0
mov ax,[si]
mov ds:[bp].0,ax
mov ax,[si+2]
mov ds:[bp].2,ax
mov ds:[bp].4,0
push si
push dx
mov si,bp
mov dh,ds:[210]
mov dl,ds:[211] ;列號(hào)
call show_str
pop dx
pop si
;收入summ 偏移5
mov ax,84[si]
mov dx,84[si+2]
push ax
push dx
push si
mov si,bp
call ddtoc
mov dh,ds:[210]
mov dl,ds:[212] ;列號(hào)
call show_str
pop si
pop dx
pop ax
add si,4
;雇員數(shù)ne 偏移10
mov bx,168[di]
add di,2
push ax
push dx
push si
mov ax,bx
mov si,bp
call dtoc
mov dh,ds:[210]
mov dl,ds:[213] ;列號(hào)
call show_str
pop si
pop dx
pop ax
;人均收入 偏移13
div bx
push ax
push dx
push si
mov si,bp
call dtoc
mov dh,ds:[210]
mov dl,ds:[214] ;列號(hào)
call show_str
pop si
pop dx
pop ax
mov cl,ds:[210]
inc cl
mov ds:[210],cl
pop cx
;loop show ;報(bào)錯(cuò)：jump destination too far ，所以自己手動(dòng)判斷cx來(lái)跳轉(zhuǎn)。
dec cx
jcxz finish
jmp show
finish:
mov ah,4CH
int 21H
;名稱：show_str
;功能：在指定位置，用指定的顏色，顯示一個(gè)用0結(jié)束的字符串
;參數(shù)：(dh)=行號(hào)，(dl)=列號(hào)，(cl)=顏色，ds:si指向字符串的首地址
show_str:
push ax
push cx
push dx
push es
push si
push di
;根據(jù)行號(hào)設(shè)置基址為bp
mov ax,160
mul dh
mov bp,ax
;根據(jù)列號(hào)設(shè)置基址為di
mov dh,0
add dx,dx ;沒個(gè)字符對(duì)應(yīng)2個(gè)字節(jié)，所以列號(hào)*2
mov di,dx
;顯存段地址
mov ax,0b800h
mov es,ax
;保存顏色屬性到al中
mov al,cl
sub cx,cx
showstr:
mov cl,[si] ;取字符
jcxz ok
mov es:[bp+di],cl ;寫字符
mov es:[bp+di].1,al ;設(shè)置顏色屬性
add di,2
inc si
loop showstr
ok:
pop di
pop si
pop es
pop dx
pop cx
pop ax
ret
;divdw
;功能：進(jìn)行不會(huì)產(chǎn)生溢出的除法運(yùn)算，被除數(shù)為dword型，除數(shù)為word型，結(jié)果為dword型
;參數(shù)：ax=dword型數(shù)據(jù)的低16位，dx=dword型數(shù)據(jù)的高16位，cx=除數(shù)
;返回：dx=結(jié)果的高16位，ax=結(jié)果的低16位，cx=余數(shù)
divdw:
push bx ;以后恢復(fù)
push ax
mov ax,dx
sub dx,dx
div cx
mov bx,ax ;bx=int(H/N)
pop ax
div cx
mov cx,dx
mov dx,bx
pop bx ;恢復(fù)bx
ret
;dtoc
;功能：將word型數(shù)據(jù)轉(zhuǎn)變?yōu)楸硎臼M(jìn)制的字符串，字符串以0為結(jié)束符
;參數(shù)：ax=word型數(shù)據(jù)；ds:si指向字符串的首地址
;返回:無(wú)
dtoc:
push ax
push bx
push cx
push dx
push si
;先插入數(shù)據(jù)結(jié)束標(biāo)記0
sub dx,dx
push dx
mov bx,10
s1:
div bx
add dx,30h ;轉(zhuǎn)為ASCII碼
push dx
mov cx,ax
jcxz ok1
sub dx,dx
jmp s1
ok1:
pop cx
jcxz ok2
mov [si],cl
inc si
jmp ok1
ok2:
;給字符串后面添0
mov [si],cl
pop si
pop dx
pop cx
pop bx
pop ax
ret
;ddtoc
;功能：將dword型數(shù)據(jù)轉(zhuǎn)變?yōu)楸硎臼M(jìn)制的字符串，字符串以0為結(jié)束符
;參數(shù)：ax=dword型數(shù)據(jù)的低16位；dx=dword型數(shù)據(jù)的高16位；ds:si指向字符串的首地址
;返回:無(wú)
ddtoc:
push ax
;push bx
push cx
push dx
push si
;先插入數(shù)據(jù)結(jié)束標(biāo)記0
sub cx,cx
push cx
dd10:
mov cx,10
call divdw
add cx,30h ;轉(zhuǎn)為ASCII碼
push cx
mov cx,ax
jcxz testhigh
jmp dd10
testhigh:
mov cx,dx
jcxz geascii
jmp dd10
geascii:
pop cx
jcxz win
mov [si],cl
inc si
jmp geascii
win:
;給字符串后面添0
mov [si],cl
pop si
pop dx
pop cx
;pop bx
pop ax
ret
CODES ENDS
END START
運(yùn)行結(jié)果如下：
總結(jié)：
1、程序?qū)崿F(xiàn)中基本都用到了棧，主要用于暫存寄存器數(shù)據(jù)。不過(guò)在子程序dtoc和ddtoc中，我還用棧存放參數(shù)%10的值，因?yàn)樾纬勺址畷r(shí)需要逆序?qū)懙絻?nèi)存。
2、在dtoc和ddtoc中，為了區(qū)分保存的寄存器數(shù)據(jù)和十進(jìn)制數(shù)的ascii值，特意往棧中壓入一個(gè)0，作為“樁”。
3、主程序中在循環(huán)跳轉(zhuǎn)的loop語(yǔ)句被注釋掉：“;loop show ;報(bào)錯(cuò)：jump destination too far ，所以自己手動(dòng)判斷cx來(lái)跳轉(zhuǎn)。”，原因正如說(shuō)明，偏移超過(guò)了一個(gè)字節(jié)，所以我自己修改判斷cx而利用jmp(jmp near)來(lái)實(shí)現(xiàn)跳轉(zhuǎn)。因?yàn)樗杏袟l件跳轉(zhuǎn)都是短轉(zhuǎn)移，是不是把循環(huán)中間的一些內(nèi)容也寫到子程序來(lái)減少偏移更好？
4、對(duì)顯示時(shí)的起始行和列偏移的數(shù)據(jù)，我都統(tǒng)一放在數(shù)據(jù)段中，可以很方便的修改來(lái)查看效果。