（引用）


{------------------------------------------------------------------------------}
{ procedure ReadStrValues                                                      }
{                                                                              }
{ 功能說明: 根據(jù)指定的分隔符將一個(gè)字符串分解為若干個(gè)子串                       }
{           如果傳遞的子串?dāng)?shù)量超過源串可以解析的字串?dāng)?shù), 則多傳的子串將置為空串 }
{ 參    數(shù):                                                                    }
{   Str   : 待分解的字符串                                                     }
{   StrArr: 存放分解后的子串的數(shù)組, 以字符串指針數(shù)組傳遞                       }
{   Ch    : 分隔符定義, 缺省為 ";"                                             }
{------------------------------------------------------------------------------}
procedure ReadStrValues(Str: string; StrArr: array of PString; Ch: Char = ';');
var
  I, StrLen, StrPos, ArrLen, ArrIndex: Integer;
begin
  StrLen := Length(Str);      // 字符串長(zhǎng)
  ArrLen := Length(StrArr);   // 待取出的字符串個(gè)數(shù)
  if ArrLen = 0 then Exit;    // 如果字符串指針數(shù)組中無元素，則直接退出

  StrPos := 1;                // 當(dāng)前讀到的字符串位置
  ArrIndex := 0;              // 當(dāng)前字符串指針數(shù)組位置

  // 此處將 Str 長(zhǎng)度加1，用于后面判斷是否已讀完整個(gè)字串
  for I := 1 to StrLen + 1 do
  begin
    // 注意此處條件位置不可倒置(驟死式判斷)
    if (I = StrLen + 1) or (Str[I] = Ch) then
    begin
      // 拷貝讀到的字符串
      StrArr[ArrIndex]^ := Copy(Str, StrPos, I - StrPos);
      StrPos := I + 1;
      // 如果需要讀的字符串指針數(shù)組已完成，則退出
      Inc(ArrIndex);
      if ArrIndex >= ArrLen then Exit;
    end;
  end;

  // 檢查是否所有的字符串指針都讀到了，如果沒有讀到，將被設(shè)置為空串
  for I := ArrIndex to ArrLen - 1 do
    StrArr[I]^ := '';
end;


{------------------------------------------------------------------------------}
{ 測(cè)試該函數(shù)                                                                   }
{------------------------------------------------------------------------------}

procedure TForm1.FormCreate(Sender: TObject);
const
  SampleStr = '張三;男;41';
var
  S1, S2, S3, S4: string;
begin
  // 正常字串解析
  S1 := 'S1';  S2 := 'S2';  S3 := 'S3';  S4 := 'S4';
  ReadStrValues(SampleStr, [@S1, @S2, @S3]);
  ShowMessage(Format('"%s", "%s", "%s", "%s"', [S1, S2, S3, S4]));

  // 待讀字串少于源串內(nèi)容測(cè)試
  S1 := 'S1';  S2 := 'S2';  S3 := 'S3';  S4 := 'S4';
  ReadStrValues(SampleStr, [@S1, @S2]);
  ShowMessage(Format('"%s", "%s", "%s", "%s"', [S1, S2, S3, S4]));

  // 待讀字串多于源串內(nèi)容測(cè)試
  S1 := 'S1';  S2 := 'S2';  S3 := 'S3';  S4 := 'S4';
  ReadStrValues(SampleStr, [@S1, @S2, @S3, @S4]);
  ShowMessage(Format('"%s", "%s", "%s", "%s"', [S1, S2, S3, S4]));

  // 待讀字串為空測(cè)試
  S1 := 'S1';  S2 := 'S2';  S3 := 'S3';  S4 := 'S4';
  ReadStrValues(SampleStr, []);
  ShowMessage(Format('"%s", "%s", "%s", "%s"', [S1, S2, S3, S4]));

  // 源串為空測(cè)試
  S1 := 'S1';  S2 := 'S2';  S3 := 'S3';  S4 := 'S4';
  ReadStrValues('', [@S1, @S2, @S3]);
  ShowMessage(Format('"%s", "%s", "%s", "%s"', [S1, S2, S3, S4]));
end;