SPXG // 標(biāo)識(shí)
// 用到5張圖片:
{
blendTexture = 0
layer0Texture = 1
layer1Texture = 2
layer2Texture = 3
layer3Texture = 4
}
!!ARBfp1.0
// 定義常量:
PARAM c[1] = { { 1, 0.30000001, 0.69999999 } };
// 聲明3個(gè)寄存器:
TEMP R0;
TEMP R1;
TEMP R2;
// 開始混合:
// 一.第0層和第1層使用第4張圖的x通道作為alpha進(jìn)行混合:
TEX R1, fragment.texcoord[0], texture[0], 2D;
TEX R0, fragment.texcoord[1], texture[1], 2D;
ADD R2, R0, -R1;
// r2=Tex1-Tex0
TEX R0, fragment.texcoord[4], texture[4], 2D;
MAD R2, R0.x, R2, R1;
// r2 = Tex4.x*r2+Tex0
// 說明:
// 其中的Tex4.x是對(duì)應(yīng)第1層alpha值, 下面把Tex4.x當(dāng)a1看
// 即 r2 = a1 * (Tex1-Tex0) + Tex0
// 轉(zhuǎn)換一下即是: Tex0*(1-a1)+a1*Tex1, 呵呵,看到了吧,這就是混合公式!
// 二.第2層和前面結(jié)果使用第4張圖的y通道作為alpha進(jìn)行混合:
TEX R1, fragment.texcoord[2], texture[2], 2D;
ADD R1, R1, -R2;
// r1=Tex2-r2
MAD R2, R0.y, R1, R2;
// r2 = Tex4.y*r1+r2, 即 a2*r1+r2 = a2*(Tex2-r2)+r2, 即r2*(1-a2)+Tex2*a2, 其中r2即是上次0和1層混合后的結(jié)果
// 三.第3層和前面結(jié)果使用第4張圖的z通道作為alpha進(jìn)行混合:
TEX R1, fragment.texcoord[3], texture[3], 2D;
ADD R1, R1, -R2;
// r1=Tex3-r2
MAD R1, R0.z, R1, R2;
// r1=a3*r1+r2 , 即 a3*r1+r2 = a3*(Tex3-r2)+r2, 即r2*(1-a3)+Tex3*a3
// 這樣r1就保存了最終的混合結(jié)果
// 四.讓陰影地表光澤系數(shù)為0(Tex4.w即a通道代表地形的陰影,0為陰影,1為正常.而每層貼圖中的a通道是光澤通道,所以R1.w保存的是最終的光澤通道值):
MUL R0.x, R1.w, R0.w;
// r0.x = r1.w(光澤)*Tex4.w(陰影值, 是陰影則=0,否則=1)
// 計(jì)算削減系數(shù)?
MAD R0.w, R0, c[0].y, c[0].z; // r0乘上0.3(削減了30％)再加上一個(gè)常量0.69999999
// 反射高光 = secondary_color(反射光)*光澤:
MUL R0.xyz, R0.x, fragment.color.secondary;
// 貼圖最終color = 最終貼圖混出的color*削減系數(shù):
MUL R1.xyz, R1, R0.w;
// 貼圖最終color * primary_color(光照色或是頂點(diǎn)色) + 反射高光:
MAD result.color.xyz, R1, fragment.color.primary, R0;
// alpha:
MOV result.color.w, c[0].x;
END
本文來自CSDN博客，轉(zhuǎn)載請(qǐng)標(biāo)明出處：http://blog.csdn.net/flipcode/archive/2008/03/03/2143452.aspx