可能大家或多或少都在qmake的.pro/.pri文件中見過這種代碼
TEMPLATE += fakelib
MY_NAME = $$qtLibraryTarget(dbzhang800)
TEMPLATE -= fakelib
如果真的沒見過，或許可以從這兒入手分析與學習Qt Solution對qmake的使用
$$qtLibraryTarget 有什么用
我們知道，在Window下，動態庫的 Debug 和 Release 版不能通用，所以要放置在不同的路徑下或者取不同的名字。在Qt下，我們經常見到
QtCore4.dll
QtCored4.dll
而當我們自己的工程中需要動態庫時，要想在兼顧各個平臺下，給它取個合適的名字還是有點小小的挑戰的。
既然Qt已經能處理自己的動態庫，我們不妨直接借用它提供的機制，這便是
$$qtLibraryTarget
作用：為各個平臺下的庫生成合適的名字
位置：$QTDIR/mkspecs/features/qt_functions.prf
具體代碼：
defineReplace(qtLibraryTarget) {
unset(LIBRARY_NAME)
LIBRARY_NAME = $$1
mac:!static:contains(QT_CONFIG, qt_framework) {
QMAKE_FRAMEWORK_BUNDLE_NAME = $$LIBRARY_NAME
export(QMAKE_FRAMEWORK_BUNDLE_NAME)
}
contains(TEMPLATE, .*lib):CONFIG(debug, debug|release) {
!debug_and_release|build_pass {
mac:RET = $$member(LIBRARY_NAME, 0)_debug
else:win32:RET = $$member(LIBRARY_NAME, 0)d
}
}
isEmpty(RET):RET = $$LIBRARY_NAME
return($$RET)
}
注：這是Qt4.8下的文件，Qt5.0下與此小有不同。
從這兒你可以看到，在windows下它何時會添加一個d，何時不會。
fakelib 干嘛用的
從前面的代碼中，我們看到有這么一句
contains(TEMPLATE, .*lib)
可是，當構建動態庫時，不是TEMPLATE確實就是 lib/vclib這些了么？
恩，構建時沒有問題，可是當使用時呢？比如
TEMPLATE = app
SOURCES += main.cpp
LIBS += $$qtLibraryTarget(dbzhang800)
還能工作么？
恩，所以了。就需要隨便取一個 xxxxxlib 作為模板來哄騙一下它。
還沒結束？
自從認識它以后，一直在自己的程序中大量使用這個東西。但是有一件事情總是讓人感覺不爽。
使用它以后：
qmake -tp vc
生成的MSVC的工程文件中，總是不能得到正確庫文件的名字（具體一點，就是Debug模式下沒有那個d）
自己用也沒什么，反正也不是什么大問題。只是沒想到解決方案竟是這樣
SAVE_TEMPLATE = $$TEMPLATE
TEMPLATE = fakelib
MY_NAME = $$qtLibraryTarget(dbzhang800)
TEMPLATE = $$SAVE_TEMPLATE
原因
當qmake使用了 -tp 選項后，對TEMPLATE處理時，只接受一個值。也就是 += 操作對其無效。
具體一點，位于qmake源碼 project.cpp 的3043行
} else if(var == QLatin1String("TEMPLATE")) {
if(!Option::user_template.isEmpty()) {
var = ".BUILTIN.USER." + var;
place[var] = QStringList(Option::user_template);
} else {
QString orig_template, real_template;
if(!place[var].isEmpty())
orig_template = place[var].first();
real_template = orig_template.isEmpty() ? "app" : orig_template;
if(!Option::user_template_prefix.isEmpty() && !orig_template.startsWith(Option::user_template_prefix))
real_template.prepend(Option::user_template_prefix);
if(real_template != orig_template) {
var = ".BUILTIN." + var;
place[var] = QStringList(real_template);
}
}