大龍的博客

分頁管理機(jī)制（線性地址轉(zhuǎn)換到物理地址）

   80386開始支持存儲(chǔ)器分頁管理機(jī)制。分頁機(jī)制是存儲(chǔ)器管理機(jī)制的第3二部分。段管理機(jī)制實(shí)現(xiàn)虛擬地址(由段和偏移構(gòu)成的邏輯地址)到線性地址的轉(zhuǎn)換，分頁管理機(jī)制實(shí)現(xiàn)線性地址到物理地址的轉(zhuǎn)換。如果不啟用分頁管理機(jī)制，那么線性地址就是物理地址。本文將介紹80386的存儲(chǔ)器分頁管理機(jī)制和線性地址如何轉(zhuǎn)換為物理地址。

<一>存儲(chǔ)器分頁管理機(jī)制

<二>線性地址到物理地址的轉(zhuǎn)換

1.映射表結(jié)構(gòu)

2.表項(xiàng)格式

頁目錄表或頁
表的表項(xiàng)格式 BIT31—BIT12 BIT11—BIT9 BIT8 BIT7 BIT6 BIT5 BIT4 BIT3 BIT2 BIT1 BIT0 物理頁碼 AVL 0 0 D A 0 0 U/S R/W P

3.線性地址到物理地址的轉(zhuǎn)換

    mov     eax,cr3
mov     cr3,eax

 

 

4.不存在的頁表

5.頁的共享

<三>頁級(jí)保護(hù)和虛擬存儲(chǔ)器支持

1.頁級(jí)保護(hù)

頁級(jí)
保護(hù)
屬性 U/S R/W 用戶級(jí)訪問權(quán)限系統(tǒng)級(jí)訪問權(quán)限 0 0 無讀/寫/執(zhí)行 0 1 無讀/寫/執(zhí)行 1 0 讀/執(zhí)行讀/寫/執(zhí)行 1 1 讀/寫/執(zhí)行讀/寫/執(zhí)行

組合頁的
保護(hù)>屬性目錄表項(xiàng)U/S 頁表項(xiàng)U/S 組合U/S 目錄表項(xiàng)R/W 頁表項(xiàng)R/W 組合R/W 0 0 0 0 0 0 0 1 0 0 1 0 1 0 0 1 0 0 1 1 1 1 1 1

2.對(duì)虛擬存儲(chǔ)器的支持

<四>頁異常

出錯(cuò)碼
的格式 BIT15—BIT3 BIT2 BIT1 BIT0 未使用 U W P

<五>演示分頁機(jī)制的實(shí)例(實(shí)例十)

1.演示步驟和源程序清單

;名稱:ASM10.ASM
;功能:演示使用分頁管理機(jī)制
;編譯:TASM ASM10.ASM
;連接:TLINK ASM10.OBJ
;============================================================================
INCLUDE         386SCD.INC
;============================================================================
PDT_AD          =       200000h ;頁目錄表所在物理頁的地址
PT0_AD          =       202000h ;頁表0所在物理頁的地址
PT1_AD          =       201000h ;頁表1所在物理頁的地址
PhVB_AD         =       0b8000h ;物理視頻緩沖區(qū)地址
LoVB_AD         =       0f0000h ;程序使用的邏輯視頻緩沖區(qū)地址
MPVB_AD         =       301000h ;線性地址0B8000H所映射的物理地址
PhSC_AD         =       303000h ;部分演示代碼所在內(nèi)存的物理地址
LoSC_AD         =       402000h ;部分演示代碼的邏輯地址
;============================================================================
GDTSeg          SEGMENT PARA USE16                ;全局描述符表數(shù)據(jù)段(16位)
;----------------------------------------------------------------------------
;全局描述符表GDT
GDT             LABEL   BYTE
;空描述符
DUMMY           Desc    <>
;規(guī)范段描述符及選擇子
Normal          Desc    <0ffffh,,,ATDW,,>
Normal_Sel      =       Normal-GDT
;頁目錄表所在段描述符(在保護(hù)方式下初始化時(shí)用)及選擇子
PDT             Desc    <0fffh,PDT_AD AND 0ffffh,PDT_AD SHR 16,ATDW,,>
PDT_Sel         =       PDT-GDT
;頁表0所在段描述符(在保護(hù)方式下初始化時(shí)用)及選擇子
PT0             Desc    <0fffh,PT0_AD AND 0ffffh,PT0_AD SHR 16,ATDW,,>
PT0_Sel         =       PT0-GDT
;頁表1所在段描述符(在保護(hù)方式下初始化時(shí)用)及選擇子
PT1             Desc    <0fffh,PT1_AD AND 0ffffh,PT1_AD SHR 16,ATDW,,>
PT1_Sel         =       PT1-GDT
;邏輯視頻緩沖區(qū)段描述符及選擇子
LoVideo         Desc    <3999,LoVB_AD AND 0ffffh,LoVB_AD SHR 16,ATDW,,>
LoVideo_Sel     =       LoVideo-GDT
;邏輯上的部分演示代碼段的描述符及選擇子
LoCode          Desc    <SCodeLen-1,LoSC_AD AND 0ffffh,LoSC_AD SHR 16,ATCE,,>
LoCode_Sel      =       LoCode-GDT
;預(yù)定內(nèi)存區(qū)域(用于部分演示代碼)的段描述符及選擇子
TPSCode         Desc    <SCodeLen-1,PhSC_AD AND 0ffffh,PhSC_AD SHR 16,ATDW,,>
TPSCode_Sel     =       TPSCode-GDT
;----------------------------------------------------------------------------
;以下是需額外初始化的描述符
EFFGDT          LABEL   BYTE
;臨時(shí)代碼段描述符及選擇子
TempCode        Desc    <0ffffh,TempCodeSeg,,ATCE,,>
TempCode_Sel    =       TempCode-GDT
;演示代碼段描述符及選擇子
DemoCode        Desc    <DemoCodeLen-1,DemoCodeSeg,,ATCE,,>
DemoCode_Sel    =       DemoCode-GDT
;演示任務(wù)數(shù)據(jù)段描述符及選擇子
DemoData        Desc    <DemoDataLen-1,DemoDataSeg,,ATDW,,>
DemoData_Sel    =       DemoData-GDT
;初始化時(shí)要移動(dòng)的代碼段描述符及選擇子(移動(dòng)時(shí)作為數(shù)據(jù)對(duì)待)
SCode           Desc    <SCodeLen-1,SCodeSeg,,ATDR,,>
SCode_Sel       =       SCode-GDT
;----------------------------------------------------------------------------
GDTLen          =       $-GDT                     ;全局描述符表長度
GDNum           =       ($-EFFGDT)/(SIZE Desc)    ;需特殊處理的描述符數(shù)
;----------------------------------------------------------------------------
GDTSeg          ENDS                              ;全局描述符表段定義結(jié)束
;============================================================================
;這部分代碼在初始化時(shí)被復(fù)制到預(yù)定的內(nèi)存區(qū)域,其功能是在屏幕上顯示提示信息
;----------------------------------------------------------------------------
SCodeSeg        SEGMENT PARA USE16
ASSUME  CS:SCodeSeg,DS:DemoDataSeg
;----------------------------------------------------------------------------
SBegin          PROC    FAR
mov     ax,LoVideo_Sel
mov     es,ax
mov     di,0
mov     ah,17h
mov     cx,MessLen
S1:             lodsb
stosw
loop    S1
JUMP16  DemoCode_Sel,Demo3
SBegin          ENDP
;----------------------------------------------------------------------------
MLen            =       $-SBegin
SCodeLen        =       $
SCodeSeg        ENDS
;============================================================================
DemoDataSeg     SEGMENT PARA USE16                ;演示任務(wù)數(shù)據(jù)段
Mess            DB      'Page is OK!'
MessLen         =       $-Mess
DemoDataLen     =       $
DemoDataSeg     ENDS
;============================================================================
DemoCodeSeg     SEGMENT PARA USE16                ;演示任務(wù)代碼段
ASSUME  CS:DemoCodeSeg
;----------------------------------------------------------------------------
DemoBegin       PROC    FAR
mov     ax,PDT_Sel
mov     es,ax
xor     di,di
mov     cx,1024
xor     eax,eax                   ;先把全部表項(xiàng)置成無效
rep     stosd                     ;再置表項(xiàng)0和表項(xiàng)1
mov     DWORD PTR es:[0],PT0_AD OR (USU+RWW+PL)
mov     DWORD PTR es:[4],PT1_AD OR (USU+RWW+PL)
mov     ax,PT0_Sel                ;初始化頁表0
mov     es,ax
xor     di,di
mov     cx,1024
xor     eax,eax
or      eax,USU+RWW+PL
Demo1:          stosd
add     eax,1000h                 ;先全部置成對(duì)應(yīng)等地址的
loop    Demo1                     ;物理頁,再特別設(shè)置兩廣表項(xiàng)
mov     di,(PhVB_AD SHR 12)*4
mov     DWORD PTR es:[di],MPVB_AD+USS+RWW+PL
mov     di,(LoVB_AD SHR 12)*4
mov     DWORD PTR es:[di],PhVB_AD+USU+RWR+PL
mov     ax,PT1_Sel                ;初始化頁表1
mov     es,ax
xor     di,di
mov     cx,1024
mov     eax,400000h
Demo2:          stosd                             ;先把全部表項(xiàng)設(shè)置為無效
add     eax,1000h
loop    Demo2                     ;再特別設(shè)置1項(xiàng)
mov     di,((LoSC_AD SHR 12)AND 3ffh)*4
mov     DWORD PTR es:[di],PhSC_AD+USU+RWR+PL
mov     eax,PDT_AD
mov     cr3,eax
mov     eax,cr0
or      eax,80000000h
mov     cr0,eax
jmp     SHORT PageE
PageE:          mov     ax,DemoData_Sel
mov     ds,ax
mov     si,OFFSET Mess
JUMP16  LoCode_Sel,SBegin
Demo3:          mov     eax,cr0
and     eax,7fffffffh             ;關(guān)閉分頁機(jī)制
mov     cr0,eax
jmp     SHORT PageD
PageD:          mov     ax,Normal_Sel
JUMP16  TempCode_Sel,ToDOS
DemoBegin       ENDP
;----------------------------------------------------------------------------
DemoCodeLen     =       $
DemoCodeSeg     ENDS
;============================================================================
TempCodeSeg     SEGMENT PARA USE16                ;臨時(shí)任務(wù)的代碼段
ASSUME  CS:TempCodeSeg
;----------------------------------------------------------------------------
Virtual         PROC    FAR
cld                               ;為演示在啟用分頁機(jī)制后執(zhí)
mov     ax,SCode_Sel              ;行位于較高線性地址空間中
mov     ds,ax                     ;的代碼作準(zhǔn)備
mov     ax,TPSCode_Sel
mov     es,ax
mov     si,OFFSET SBegin
mov     di,si
mov     cx,MLen                   ;把分頁演示代碼復(fù)制到預(yù)定
rep     movsb                     ;內(nèi)存
JUMP16  DemoCode_Sel,DemoBegin
ToDOS:          mov     ds,ax
mov     es,ax
mov     eax,cr0                   ;準(zhǔn)備返回實(shí)模式
and     al,11111110b
mov     cr0,eax
JUMP16  <SEG Real>,<OFFSET Real>
Virtual         ENDP
;----------------------------------------------------------------------------
TempCodeSeg     ENDS
;============================================================================
RCodeSeg        SEGMENT PARA USE16                ;實(shí)方式的初始化代碼和數(shù)據(jù)
ASSUME  CS:RCodeSeg,DS:RCodeSeg
;----------------------------------------------------------------------------
VGDTR           PDesc   <GDTLen-1,>
;----------------------------------------------------------------------------
Start           PROC
push    cs
pop     ds
cld
call    InitGDT                   ;初始化全局描述符表GDT
EnableA20
lgdt    QWORD PTR VGDTR           ;裝載GDTR
cli                               ;關(guān)中斷
mov     eax,cr0
or      al,1
mov     cr0,eax
JUMP16  <TempCode_Sel>,<OFFSET Virtual>
Real:           DisableA20
sti
mov     ax,4c00h
int     21h
Start           ENDP
;----------------------------------------------------------------------------
InitGDT         PROC
push    ds
mov     ax,GDTSeg
mov     ds,ax
mov     cx,GDNum
mov     si,OFFSET EFFGDT
InitG:          mov     ax,[si].BaseL
movzx   eax,ax
shl     eax,4
shld    edx,eax,16
mov     WORD PTR [si].BaseL,ax
mov     BYTE PTR [si].BaseM,dl
mov     BYTE PTR [si].BaseH,dh
add     si,SIZE Desc
loop    InitG
pop     ds
mov     bx,16
mov     ax,GDTSeg
mul     bx
mov     WORD PTR VGDTR.Base,ax
mov     WORD PTR VGDTR.Base+2,dx
ret
InitGDT         ENDP
;----------------------------------------------------------------------------
RCodeSeg        ENDS
END     Start
2.關(guān)于實(shí)例十的說明
    上述演示程序的許多內(nèi)容與其它實(shí)例相同，下面僅就演示分頁管理機(jī)制方面的內(nèi)容作些說明： 
(1)部分演示代碼的移動(dòng)
    為了充分說明分頁機(jī)制所實(shí)現(xiàn)的線性地址到物理地址的轉(zhuǎn)換，在初始化時(shí)把部分演示代碼移動(dòng)到預(yù)定的內(nèi)存區(qū)域。預(yù)定的內(nèi)存區(qū)域從00303000H開始，即頁碼為00303H的物理頁。該部分演示代碼的功能是顯示指定的字符串。在進(jìn)入保護(hù)模式后做此初始化工作的原因是預(yù)定的內(nèi)存區(qū)域在擴(kuò)展內(nèi)存中，注意初始化時(shí)還沒有啟用分頁機(jī)制。 
(2)頁映射表的初始化
    頁目錄表安排在頁碼為00200H的物理頁中，頁表0安排在頁碼為00202H的物理頁中，頁表1安排在頁碼為00201H的物理頁中。演示程序涉及的線性地址空間不超過007FFFFFH，所以只使用兩張頁表，為此頁目錄表中的其它項(xiàng)被置為無效(P=0)。 
    頁表0把線性地址空間中的00000000H—003FFFFFH映射到物理地址空間中。實(shí)例在初始化頁表0時(shí)，使該線性地址空間直接映射到相同地址的物理地址空間，除線性地址空間中頁碼為000B8H和000F0H這兩頁以外。000B8H頁被映射到頁碼為00301H的物理頁，而000F0H頁被映射到頁碼為000B8H的物理頁。 
    頁表1把線性地址空間中的00400000H—007FFFFFH映射到物理地址空間中。實(shí)例在初始化頁表1時(shí)，似乎使該線性地址空間直接映射到相同地址的物理地址空間，但是處理對(duì)應(yīng)線性地址空間中00402H的表項(xiàng)被另外設(shè)置外，其它表項(xiàng)中的P位為0，也即表示對(duì)應(yīng)物理頁不存在。初始化后，頁表1的第2項(xiàng)把線性地址空間中的00402H頁映射到頁碼為00303H的物理頁，也就是存放部分演示代碼的指定內(nèi)存區(qū)域。 
(3)啟動(dòng)分頁管理機(jī)制
    在建立好頁映射表后，啟用分頁機(jī)制所要做的操作是簡(jiǎn)單的，只要把控制寄存器CR0中的最高位，也就是PG位置1。具體指令如下： 
        mov     eax,cr0
or      eax,80000000h
mov     cr0,eax
jmp     SHORT PageE
PageE:  ...

    在啟用分頁機(jī)制前，線性地址就是物理地址；在啟用分頁機(jī)制后，線性地址要通過分頁機(jī)制的轉(zhuǎn)換，才成為物理地址。盡管使用一條轉(zhuǎn)移指令，可清除預(yù)取隊(duì)列，但隨后在取指令時(shí)使用的線性地址就要經(jīng)過分頁機(jī)制轉(zhuǎn)換才成為物理地址。為了順利過渡，在啟用分頁機(jī)制之后的過渡代碼段，仍要維持線性地址等同于物理地址。為了作到這一點(diǎn)，在建立也映射表時(shí)，必須使實(shí)現(xiàn)過渡的代碼所在的線性地址空間頁映射到具有相同地址的物理地址空間頁。實(shí)例中頁表0就做到了這一點(diǎn)。 
(4)關(guān)閉分頁管理機(jī)制
    只要把控制寄存器CR0中的PG位清0，便關(guān)閉了分頁機(jī)制。在這一過渡階段，也要保持地址轉(zhuǎn)換前后的一致。 
(5)地址轉(zhuǎn)換的演示
    在啟用分頁機(jī)制之后，就轉(zhuǎn)移到位于線性地址空間中00402000H處開始的代碼，該部分代碼的功能是顯示提示信息"Page is OK!"。實(shí)際上這部分代碼存放在從物理地址00303000H開始的物理內(nèi)存區(qū)域中，是在初始化時(shí)被移到此區(qū)域的。 
    在顯示提示信息時(shí)，要把顯示的ASCII字符和顯示屬性填到線性地址空間中000F0000H開始的區(qū)域中，而不是000B8000H開始的區(qū)域。從初始化時(shí)建立的映射表可見，線性地址空間中的000F0H頁，被映射到物理地址空間中的000B8H頁。所以，向線性地址空間中的000F0H頁寫，實(shí)際上是向物理地址空間中的000B8H頁寫，也就是真正顯示。 
(6)頁級(jí)保護(hù)的說明
    在進(jìn)入保護(hù)模式之后，特權(quán)級(jí)一直是0，所以，無論系統(tǒng)級(jí)和用戶級(jí)頁，無論只能讀/執(zhí)行，還是讀/執(zhí)行/寫，總是可進(jìn)行各種形式的訪問。

posted on 2010-04-15 01:19 大龍 閱讀(2886) 評(píng)論(0)  編輯 收藏 引用